;installation de JT2GoSetup à partir du fichier JT2GoSetup.exe
;JEAN-RENE DANIS 10-10-08
;Liste des variable(s)
;variable qui définit l'emplacement du fichier log
$DossierDeLog = "%systemdrive%\install\log\"
;Création du dossier pour mettre le fichier log si ce dossier n'existe pas
IF NOT EXIST ($DossierDeLog)
MD $DossierDeLog
ENDIF
;Ouverture du fichier log et redirection des messages
IF RedirectOutput($DossierDeLog + @SCRIPTNAME + ".txt") = 0
?? "Ouverture de " + @SCRIPTNAME + " à " + @TIME
ELSE
? "Impossible de créer le fichier log"
GOTO "finerreur"
ENDIF
cd @SCRIPTDIR\
;determine le dossier "program files 32 bits" en fonction de l'architecture du systeme d'exploitation
IF @ONWOW64 = 1
$progx86 = "%SYSTEMDrive%\Program Files (x86)"
ELSE
$progx86 = "%SYSTEMDrive%\Program Files"
ENDIF
? "Dossier d'installation des programme 32bits :" + $progx86
;Verifie si le programme est déjà installé
$prgatester = $progx86 + "\UGS\JT2Go\VisView.exe"
IF EXIST ($prgatester)
? "Le programme est déjà installé"
GOTO "finerreur"
ELSE
? "Le programme n'est pas déjà installé : lancement de l'installation."
ENDIF
;verifie si le systeme d'exploitation est en anglais ou en francais
IF EXIST ("%SYSTEMDrive%\Documents and Settings\Administrator")
$LNGSEI="GB"
ELSE
$LNGSEI="FR"
ENDIF
? "Langue : " + $LNGSEI
;determine le chemin du menu démarrer, tous les programmes en fonction de la langue et du systeme d'exploitation
SELECT
CASE @PRODUCTTYPE = "Windows 2000 Professional"
$ALLUSERPRG="%ALLUSERSPROFILE%\Menu Démarrer\Programmes"
CASE @PRODUCTTYPE = "Windows XP Professional"
IF $LNGSEI="FR"
$ALLUSERPRG="%ALLUSERSPROFILE%\Menu Démarrer\Programmes"
ELSE
IF $LNGSEI="GB"
$ALLUSERPRG ="%ALLUSERSPROFILE%\Start Menu\Programs"
ENDIF
ENDIF
CASE @PRODUCTTYPE = "Windows Vista Business Edition"
$ALLUSERPRG = "%ProgramData%\Microsoft\Windows\Start Menu\Programs"
ENDSELECT
? "Chemin du menu démarrer\tous les programmes : " + $ALLUSERPRG
;determine le chemin du dossier du bureau en fonction de la langue et du system d'exploitation
Select
Case @PRODUCTTYPE = "Windows 2000 Professional"
$ALLUSERBUREAU = "%ALLUSERSPROFILE%\bureau"
Case @PRODUCTTYPE = "Windows XP Professional"
IF $LNGSEI="FR"
$ALLUSERBUREAU = "%ALLUSERSPROFILE%\bureau"
ELSE
IF $LNGSEI="GB"
$ALLUSERBUREAU = "%ALLUSERSPROFILE%\Desktop"
ENDIF
ENDIF
Case @PRODUCTTYPE = "Windows Vista Business Edition"
$ALLUSERBUREAU = "%public%\desktop"
EndSelect
? "Chemin du bureau : " + $ALLUSERBUREAU
;installation du programme
$commande='JT2GoSetup.exe /s /v"/passive /norestart AGREE_TO_JT2GO_LICENSE=Yes INSTALLDIR=\"' + $progx86 + '\UGS\JT2Go\" ALLUSERS=2"'
? $commande
shell '%COMSPEC% /c ' + $commande
IF @ERROR <> 0
? "Erreur n° " + @ERROR
GOTO "finerreur"
ENDIF
;Si le dossier "menu démarrer\viewers" n'existe : le créer
IF ADDPROGRAMGROUP ("Viewers",1) = 0
? "Dossier Viewers créé ou exist déjà"
ELSE
? "Erreur création dossier Viewers"
GOTO "Finerreur"
ENDIF
;Déplacement du raccourci dans dossier "menu démarrer\viewers"
MOVE $ALLUSERPRG + '\UGS Teamcenter 2007\Lifecycle Visualization\' $ALLUSERPRG + "\Viewers\UGS JT2Go\"
DELPROGRAMGROUP ('UGS Teamcenter 2007',1)
;Suppression du raccourci du bureau
$racc_bureau = "JT2Go.lnk"
? "Efface le raccourci : "+ $ALLUSERBUREAU + "\" + $racc_bureau
DEL $ALLUSERBUREAU + "\" + $racc_bureau
GOTO "fin"
;label de fin avec erreurs
:finerreur
? "fin du script d'installation : erreur"
;Ouverture du fichier log pour signaler la présence d'erreurs
IF RedirectOutput($DossierDeLog + "ERREUR_" + @SCRIPTNAME +".txt") = 0
?? "Ouverture de erreur_" + @SCRIPTNAME + " à " + @TIME
? "le script d'installation à rencontrer des erreurs : consulter le fichier log :"
? $DossierDeLog + @SCRIPTNAME +".txt"
ENDIF
sleep 5
;label de fin sans erreurs
:fin
? "fin du script d'installation"
;annule la redirection vers un fichier
RedirectOutput("")
|
