;installation de DWG True View 2009 à partir des fichiers SetupDWGTrueView2009_32bit_FRA.exe ou SetupDWGTrueView2009_64bit_FRA.exe
;JEAN-RENE DANIS 15-10-08
;Mise à jour le 08/01/09 pour continuer le script même si les programmes dépendants renvoient un code d'erreur
;Liste des variable(s)
;variable qui définit l'emplacement du fichier log
$DossierDeLog = "%systemdrive%\install\log\"
;variable qui définit la destination temporaire :
$dossierprov = '%systemdrive%\install\SetupDWGTrueView2009_fra'
;variable qui définit le dossier de 7Zip ou se trouve 7z.exe :
$SEI_7Z = '%SYSTEMDrive%\Program Files\7-Zip'
;Création du dossier pour mettre le fichier log si ce dossier n'existe pas
IF NOT EXIST ($DossierDeLog)
MD $DossierDeLog
ENDIF
;Ouverture du fichier log et redirection des messages
IF RedirectOutput($DossierDeLog + @SCRIPTNAME + ".txt") = 0
?? "Ouverture de " + @SCRIPTNAME + " à " + @TIME
ELSE
? "Impossible de créer le fichier log"
GOTO "finerreur"
ENDIF
cd @SCRIPTDIR\
;Verifie si le programme est déjà installé et affiche sa version
$prgatester = "%systemdrive%\Program Files\DWG TrueView 2009\DWGVIEWR.exe"
IF EXIST ($prgatester)
? "Le programme est déjà installé"
GOTO "finerreur"
ELSE
? "Le programme n'est pas déjà installé : lancement de l'installation."
ENDIF
;creation du dossier de destination
IF NOT EXIST ($dossierprov)
MD $dossierprov
? "Le dossier : " + $dossierprov + " a été créé."
ELSE
? "Le dossier : " + $dossierprov + " existe déjà."
ENDIF
;décompression d'un fichier en fonction de l'architecture du system d'exploitation
IF @ONWOW64 = 1
$fichieradecomp = 'SetupDWGTrueView2009_64bit_FRA.exe'
ELSE
$fichieradecomp = 'SetupDWGTrueView2009_32bit_FRA.exe'
ENDIF
? "Fichier à décomprimer : $fichieradecomp"
$destinationdeladecomp = $dossierprov
$commande='"$SEI_7Z\7z.exe" x -o$destinationdeladecomp\ $fichieradecomp'
? $commande
shell '%COMSPEC% /c ' + $commande
IF @ERROR <> 0
? "Erreur 7z n° " + @ERROR
GOTO "finerreur"
ENDIF
;determine le chemin du menu démarrer, tous les programmes en fonction de la langue et du systeme d'exploitation
$ALLUSERPRG=readvalue("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders","Common Programs")
? "Chemin du menu démarrer\tous les programmes : " + $ALLUSERPRG
;determine le chemin du burreau de tous les utilisateurs
$ALLUSERBUREAU=readvalue("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders","Common Desktop")
? "Chemin du bureau : " + $ALLUSERBUREAU
;Verifi si un dossier existe
IF NOT EXIST ($ALLUSERPRG + "\Autodesk\")
? "Le dossier " + $ALLUSERPRG + "\Autodesk\ existe déjà"
$drapeauautodesk = 1
ENDIF
;installation du programme dépendant en fonction de l'architecture du system d'exploitation
IF @ONWOW64 = 1
$commande='$dossierprov\support\dotnetfx\netfx64.exe /q /norestart'
ELSE
$commande='$dossierprov\support\dotnetfx\dotnetfx.exe /q /norestart'
ENDIF
? $commande
shell '%COMSPEC% /c ' + $commande
IF @ERROR <> 0
? "Erreur n° " + @ERROR
ENDIF
;installation du programme dépendant
$commande='$dossierprov\support\dotnetfx\1036\langpack.exe /q /norestart'
? $commande
shell '%COMSPEC% /c ' + $commande
IF @ERROR <> 0
? "Erreur n° " + @ERROR
ENDIF
;installation du programme dépendant en fonction de l'architecture du system d'exploitation
IF @ONWOW64 = 1
$commande='msiexec /i $dossierprov\support\msxml\msxml6_x64.msi /passive /norestart'
ELSE
$commande='msiexec /i $dossierprov\support\msxml\msxml6.msi /passive /norestart'
ENDIF
? $commande
shell '%COMSPEC% /c ' + $commande
IF @ERROR <> 0
? "Erreur n° " + @ERROR
ENDIF
;installation du programme dépendant en fonction de l'architecture du system d'exploitation
IF @ONWOW64 = 1
$commande='msiexec /i $dossierprov\support\VCRedist\x64\vcredist.msi /passive /norestart'
ELSE
$commande='msiexec /i $dossierprov\support\VCRedist\x86\vcredist.msi /passive /norestart'
ENDIF
? $commande
shell '%COMSPEC% /c ' + $commande
IF @ERROR <> 0
? "Erreur n° " + @ERROR
ENDIF
;installation du programme
$commande='msiexec /i $dossierprov\DWGVIEWR.msi /passive /norestart'
? $commande
shell '%COMSPEC% /c ' + $commande
IF @ERROR <> 0
? "Erreur n° " + @ERROR
GOTO "finerreur"
ENDIF
;Si le dossier "menu démarrer\viewers" n'existe : le créer
IF NOT EXIST ($ALLUSERPRG + "\Viewers\Autodesk")
? "création du dossier " + $ALLUSERPRG + "\Viewers\Autodesk"
MD $ALLUSERPRG + "\Viewers\Autodesk"
IF @ERROR <> 0
? "Erreur n° " + @ERROR
GOTO "finerreur"
ENDIF
ELSE
? "Le dossier " + $ALLUSERPRG + "\Viewers\Autodesk existe déjà"
ENDIF
;Déplacement du raccourci dans dossier "menu démarrer\viewers"
MOVE $ALLUSERPRG + '\Autodesk\DWG TrueView 2009\' $ALLUSERPRG + "\Viewers\Autodesk\DWG TrueView 2009\"
IF $drapeauautodesk
DELPROGRAMGROUP ("Autodesk", 1)
ENDIF
;efface du raccourci sur le bureau
del "$ALLUSERBUREAU\DWG TrueView 2009 - Français.lnk"
;effacement d'un dossier
$dossierasupprimer = $dossierprov
del $dossierasupprimer + "\*.*" /c /f /s
rd $dossierasupprimer /s
IF NOT EXIST ($dossierasupprimer)
? "Le dossier : " + $dossierasupprimer + " a été supprimé"
ELSE
? "Le dossier : " + $dossierasupprimer + " n'a pas été supprimé complétement"
ENDIF
GOTO "fin"
;label de fin avec erreurs
:finerreur
? "fin du script d'installation : erreur"
;Ouverture du fichier log pour signaler la présence d'erreurs
IF RedirectOutput($DossierDeLog + "ERREUR_" + @SCRIPTNAME +".txt") = 0
?? "Ouverture de erreur_" + @SCRIPTNAME + " à " + @TIME
? "le script d'installation à rencontrer des erreurs : consulter le fichier log :"
? $DossierDeLog + @SCRIPTNAME +".txt"
ENDIF
sleep 5
;label de fin sans erreurs
:fin
? "fin du script d'installation"
;annule la redirection vers un fichier
RedirectOutput("")
|
